Parsing the Cricinfo DRS text

NB this post may be of limited interest (read: zero interest) to anybody but me.

Cricinfo records Umpire Decision Review System (DRS or UDRS) outcomes in its match notes. Here are a few examples:

• Over 18.2: Refferal by South Africa, Umpire- SJ Davis, Batsman- AG Prince(Upheld)
• Over 39.2: Referral by England, Umpire- Aleem Dar, Batsman- JH Kallis (Struck down)
• Over 3.5: Review by Australia (Bowling), Umpire - Aleem Dar, Batsman - IJL Trott (Struck down)
• 34.5: Referral by Australia, Umpire-MR Benson, Batsman - S Chanderpaul (Struck down)
• Over 103.1 Referral by West Indies, Umpire-IJ Gould, Batsman - SJ Benn (Struck down)
• Over 16.3; Referral by Australia, Umpire BF Bowden, Batsman-SR Watson (Struck down)

Here, as far as I can make out, is the ABNF describing the Cricinfo match notes that tell us about DRS outcomes:

Review-text     = ["Over" 1*WSP] Over-ball [":" / ";"] Review-name Team [Role] ", " Umpire ", " Batsman Outcome

Over-ball       = 1*3DIGIT "." Ball ; When the review happened in the innings

Ball            = %x30-36 ; 0-6 (assuming 6-ball overs)

Review-name     = 1*WSP ["Review" / "Referral" / "Refferal"] " by " ; Has been referred to using various names (and typos)

Team            = "England"
                / "Australia"
                / "South Africa"
                / "India"
                / "Pakistan"
                / "Sri Lanka"
                / "West Indies"
                / "New Zealand"
                / ICC-member

ICC-member      = 1*ALPHA ; Unique string identifying the team asking for the review

Role            = 1*WSP "(" ("Batting" / "Bowling") ")"

Umpire          = "Umpire" [*WSP "-" *WSP] Umpire-name

Umpire-name     = 1*ALPHA

Batsman         = "Batsman" [*WSP "-" *WSP] Batsman-name

Batsman-name    = 1*ALPHA

Outcome         = *WSP "(" ("Upheld" / "Struck down") ")"